Subject: BAT mode, take 2

From: Peter Breton <[email-masked]>
Date: Thu, 22 Aug 96 21:22:00 EDT

Some bug fixes and cleanups, better font-lock support.

Credit for suggestions to:

   Robert Brodersen <[email-masked]>
   [email-masked] (Alfred Correira)

;;; my-batmode.el --- Simple mode for Windows BAT files

;; Author: Peter Breton <[email-masked]> 
;; Created: Thu Jul 25 1996
;; Version: $Id: my-batmode.el,v 1.3 1996/08/22 02:31:47 peter Exp $
;; Keywords: 
;; Time-stamp: <96/08/20 21:18:01 peter>

;;; Commentary:
;;
;; USAGE: Byte-compile this file, and add the following line to your
;;   emacs initialization file (.emacs/_emacs):
;; 
;; (setq auto-mode-alist 
;;       (append 
;;        (list (cons "\\.[bB][aA][tT]$" 'bat-mode))
;;        ;; For DOS init files
;;        (list (cons "CONFIG\\."   'bat-mode))
;;        (list (cons "AUTOEXEC\\." 'bat-mode))
;;        auto-mode-alist))

;; TODO:
;;
;; Support "compiles" ?
;; Imenu? Don't have real functions.....

;;; Change log:
;; $Log: my-batmode.el,v $
;; Revision 1.3  1996/08/22 02:31:47  peter
;; Added Usage message, credit to folks from NTEmacs mailing list,
;; Syntax table, New font-lock keywords
;;
;; Revision 1.2  1996/08/18 16:27:13  peter
;; Added preliminary global-font-lock support
;;
;; Revision 1.1  1996/08/18 16:14:18  peter
;; Initial revision
;;

;; Credit for suggestions, patches and bug-fixes:
;;   Robert Brodersen <[email-masked]>
;;   [email-masked] (Alfred Correira)

;;; Code:

(defvar bat-mode-map nil "Local keymap for bat-mode buffers.")

;; Make this lowercase if you like
(defvar bat-mode-comment-start "REM "
  "Comment string to use in BAT mode")

(defvar bat-mode-syntax-table nil
  "Syntax table in use in Bat-mode buffers.")

(if bat-mode-map
    nil
  (setq bat-mode-map (copy-keymap global-map))
)

;; Make underscores count as words
(if bat-mode-syntax-table
    ()
  (setq bat-mode-syntax-table (make-syntax-table))
  (modify-syntax-entry ?_  "w"  bat-mode-syntax-table)
)

(defun bat-mode ()
  "Mode for DOS and Windows BAT files"
  (interactive)
  (use-local-map             bat-mode-map)
  (set-syntax-table	     bat-mode-syntax-table)

  (make-local-variable	     'parse-sexp-ignore-comments)
  (make-local-variable	     'comment-start)
  (make-local-variable	     'comment-start-skip)
  (make-local-variable	     'comment-end)
  (make-local-variable	     'executable-command)

  (setq major-mode          'bat-mode
        mode-name           "bat"

        comment-end         ""

       comment-start       bat-mode-comment-start
       comment-start-skip  "[Rr][Ee][Mm] *"

       parse-sexp-ignore-comments t
       
       )

  ;; Global font-lock support; I think more is required
  (and (boundp 'font-lock-global-modes)
       font-lock-global-modes
       (font-lock-mode t))

  (run-hooks 'bat-mode-hook))

(defvar bat-font-lock-keywords
  (list
   ;; Make this one first in the list, otherwise comments will
   ;; be over-written by other variables
    (list "^[@	]*\\([rR][eE][mM].*\\)" 1 'font-lock-comment-face t)
    (list "^[	]*\\(::-.*\\)"		1 'font-lock-comment-face t)
    (list
     (concat "\\(\\<"
      (mapconcat 'identity
                 '(
                   "call"
                   "echo"
                   "exist"
                   "errorlevel"
                   "for"
                   "goto"
                   "if"
                   "not"
                   "path"
                   "pause"
                   "prompt"
                   "set"
                   "start"
                  )
                 "\\>\\|\\<")
             "\\>\\)") 1 'font-lock-keyword-face)
	(list "^[	]*\\(:\\sw+\\)"  1 'font-lock-function-name-face t)
	(list "\\(%\\sw+%\\)"		 1 'font-lock-reference-face)
	(list "\\(%[0-9]\\)"		 1 'font-lock-reference-face)
	(list "\\(/[^/	]+\\)"		 1 'font-lock-type-face)
	(list "\\<\\(goto\\)\\>[	]*\\(\\sw+\\)?" 
	      '(1 font-lock-keyword-face)
	      '(2 font-lock-function-name-face nil t))

  )
  "Keywords to hilight in BAT mode")

;;; don't do it in Win-Emacs
(if (boundp 'font-lock-defaults-alist)
    (add-to-list
     'font-lock-defaults-alist 
     (cons 'bat-mode
	   (list 'bat-font-lock-keywords nil t nil nil))))

(provide 'bat-mode)

;;; my-batmode.el ends here

;; Local Variables:
;; autocompile: t
;; End: